sub to-min(Str $str) {
    do given $str.comb(/\d+/) {
       60*.[0] + .[1]
    }
}

proto calc(Int $count,  Int $prev, @in,               @out --> Int) {*}
multi calc(0,           Int,       [],                []   --> 0)   {}
multi calc(Int,         Int,       [],                [])           { die "Finished with guest inside house" }
multi calc(0,           Int $prev, [Int $in, *@in],   @out where $in <= *.head)        { calc 1, $in, @in, @out }
multi calc(Int $count,  Int $prev, [Int $in, *@in],   @out where $in <= *.head)        { $in  - $prev + calc $count + 1, $in,  @in, @out }
multi calc(Int $count,  Int $prev, @in (Int $in, *@), [Int $out where $in > *, *@out]) { $out - $prev + calc $count - 1, $out, @in, @out }
multi calc(Int $count,  Int $prev, [],                [Int $out, *@out])               { $out - $prev + calc $count - 1, $out, [],  @out }

my (@in, @out) := ([[],[]], |lines).reduce: -> (@in, @out), $_ {
   my ($in, $out) = .comb(/\d+":"\d+/);
   [ |@in, to-min $in, ], [ |@out, to-min $out ]
}

say calc 0, 0, @in.sort, @out.sort

multi calc(@mem,                        Int $num) { [ $num, |@mem ]   }
multi calc([Int() $x, Int() $y, *@mem], "+"     ) { [ $y + $x, |@mem] }
multi calc([Int() $x, Int() $y, *@mem], "-"     ) { [ $y - $x, |@mem] }
multi calc([Int() $x, Int() $y, *@mem], "−"     ) { [ $y - $x, |@mem] }
multi calc([Int() $x, Int() $y, *@mem], "*"     ) { [ $y * $x, |@mem] }
multi calc([Int() $x, Int() $y, *@mem], "×"     ) { [ $y * $x, |@mem] }
multi calc([Int() $x, Int() $y, *@mem], "/"     ) { [ $y / $x, |@mem] }
multi calc([Int() $x, Int() $y, *@mem], "÷"     ) { [ $y / $x, |@mem] }
multi calc(@mem (Int() $x, *@),         "="     ) { @mem              }

my @mem;
for words() {
    @mem = calc @mem, .&val;
    say @mem.head
}